LlosLab Software Development BlogEngineering notes for PDF, Delphi, and document software developers.

Articolo tecnico

Tabella HotPDF in PDF

· Software PDF

Questo esempio del componente HotPDF converte i record del database in una tabella PDF paginata. È un modello compatto per la generazione di report: legge le righe da un set di dati, disegna l'intestazione della tabella, stampa ogni riga in una posizione verticale nota e aggiunge una nuova pagina quando la pagina corrente è piena.

L'esempio utilizza una sorgente dati TTable legacy, ma la logica PDF è indipendente da tale livello di archiviazione. Lo stesso approccio di rendering può essere utilizzato con FireDAC, ADO, set di dati in memoria, risultati REST o qualsiasi dato dell'applicazione che possa essere enumerato riga per riga.

Il punto chiave della progettazione è separare il rendering delle righe dalla configurazione della pagina. PrintRow disegna una riga, PreparePage crea l'intestazione ripetuta e i metadati della pagina, e il ciclo principale controlla la paginazione. Tale separazione rende l'esempio più facile da adattare a tabelle più ampie, totali, raggruppamenti o intestazioni di report personalizzate.

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
program TableDemo;
{$APPTYPE CONSOLE}
{ Reduce EXE size by disabling as much of RTTI as possible }
{$IFDEF VER210}
{$WEAKLINKRTTI ON}
{$RTTI EXPLICIT METHODS([]) PROPERTIES([]) FIELDS([])}
{$ENDIF}
 
uses
  {$IFDEF VER230}System.Classes, System.SysUtils, Vcl.Graphics, DB, DBTables,
  {$ELSE} Classes, SysUtils, Graphics, DB, DBTables,
  {$ENDIF} HPDFDoc;
 
var
  HotPDF: THotPDF;
  PageNum, VertPos: Integer;
  CustomerTable: TTable;
  Back: boolean;
 
procedure PrintRow(Position: Integer; No, Company, Addr, City: AnsiString; ShowBackground: boolean);
begin
  if ShowBackground then
  begin
    HotPDF.CurrentPage.SetRGBColor($FFF3DD);
    HotPDF.CurrentPage.Rectangle(50, Position, 520, 20);
    HotPDF.CurrentPage.Fill;
    HotPDF.CurrentPage.SetRGBColor(clBlack);
  end;
  HotPDF.CurrentPage.TextOut(70, Position, 0, No);
  HotPDF.CurrentPage.TextOut(110, Position, 0, Company);
  HotPDF.CurrentPage.TextOut(300, Position, 0, Addr);
  HotPDF.CurrentPage.TextOut(480, Position, 0, City);
end;
 
procedure PreparePage;
begin
  HotPDF.CurrentPage.SetFont('Arial', [fsItalic], 10);
  HotPDF.CurrentPage.TextOut(50, VertPos, 0, 'customer.db' + '  Page' + AnsiString(IntToStr(PageNum)));
  HotPDF.CurrentPage.TextOut(480, VertPos, 0, AnsiString(DateTimeToStr(Now)));
  HotPDF.CurrentPage.MoveTo(50, VertPos + 15);
  HotPDF.CurrentPage.LineTo(570, VertPos + 15);
  HotPDF.CurrentPage.MoveTo(50, VertPos + 45);
  HotPDF.CurrentPage.LineTo(570, VertPos + 45);
  HotPDF.CurrentPage.Stroke;
  HotPDF.CurrentPage.SetFont('Times New Roman', [fsItalic, fsBold], 12);
  HotPDF.CurrentPage.SetRGBFillColor(clNavy);
  PrintRow(VertPos + 25, 'No', 'Company', 'Addr', 'City', false);
  HotPDF.CurrentPage.SetRGBFillColor(clBlack);
  Inc(VertPos, 20);
end;
 
begin
  CustomerTable := TTable.Create(nil);
  try
    CustomerTable.DatabaseName := 'DBDEMOS';
    CustomerTable.TableName := GetCurrentDir + '\customer.db';
    CustomerTable.Active := true;
    CustomerTable.First;
    HotPDF := THotPDF.Create(nil);
    try
      HotPDF.AutoLaunch := true;
      HotPDF.FileName := 'TableDemo.pdf';
      HotPDF.PageLayout := plOneColumn;
      HotPDF.BeginDoc;
      HotPDF.CurrentPage.SetFont('Arial', [fsBold], 24);
      HotPDF.CurrentPage.TextOut(200, 20, 0, 'Customer report'); // Print PDF header
      PageNum := 1;
      VertPos := 60;
      PreparePage; // Table header
      Back := true;
      while (not(CustomerTable.Eof)) do
      begin
        Back := not(Back);
        if (VertPos > 700) then // If end of page then
        begin
          HotPDF.AddPage; // Add page, draw and print
          Inc(PageNum);   // table header and set
          VertPos := 60;  // new print position
          PreparePage;
        end;
        PrintRow(VertPos + 25, // print row from the current position
          AnsiString(CustomerTable.FieldValues['CustNo']), AnsiString(CustomerTable.FieldValues['Company']),
          AnsiString(CustomerTable.FieldValues['Addr1']), AnsiString(CustomerTable.FieldValues['City']), Back);
        Inc(VertPos, 20);
        CustomerTable.Next;
      end;
      HotPDF.EndDoc;
    finally
      HotPDF.Free;
    end;
  finally
    CustomerTable.Free;
  end;
 
end.

Cosa adattare in produzione

  • Sostituire la tabella DBDEMOS di esempio con il set di dati o il risultato della query dell'applicazione.
  • Misurare le larghezze delle colonne in base ai dati previsti invece di codificare rigidamente ogni coordinata x.
  • Gestire il testo lungo avvolgendo o troncando i campi prima di disegnare la riga.
  • Ripetere le intestazioni delle tabelle su ogni nuova pagina in modo che i report esportati rimangano leggibili.
  • Mantenere i margini della pagina e l'altezza delle righe in costanti denominate rende le modifiche al layout più prevedibili.

Perché il disegno diretto delle tabelle PDF è utile.

Il disegno diretto offre il controllo completo su font, colori, bordi, interruzioni di pagina e righe di riepilogo, senza dipendere da un designer di report visivo. È particolarmente utile per strumenti lato server o per processi batch in cui il formato di output deve rimanere stabile su diverse macchine.